need some help with this program

need some help with this program

Jannes Braet 16 Nov 2013 18:06

Hello I wrote a program but it is not working really good.
I wanted it to be filling up my screen so that I could see it pixel by pixel but instead it loads a few seconds and then it shows me this

Can anyone tell me how to fix that line in there and how to update my graph everytime I add a pixel? This is my code:

#include "ti83plus.inc"
.org $9D93
.db $BB,$6D ; AsmPrgm
;.define bcall(label) rst $28 \ .dw label

start:
    ld c,00h ;y
outer:
    inc c
    Ld b,00h ;x
inner:
    inc b

;__________pixel-on(b,c)_______________
    push bc ;store values of b and c for the loops

    ld h,00h
    ld l,b
    ld d,h
    ld e,l
    add hl,hl
    add hl,de
    add hl,hl
    add hl,hl ;b*12

    ld d,00h 
    srl c
    rl d
    srl c
    rl d
    srl c
    rl d  ;c is integer part of c/8 and d is the rest of the division
    push de ;store the d register
    ld d,00h
    ld e,c
    add hl,de ;hl=b*12 + c/8
    ld d,93h
    ld e,40h
    add hl,de ;add hl,9340h ;putSScreen
    pop de ;recall d register

    push de ;store it again
    rlc (hl) ;CB06 
    dec d ;15
    jr nz,$-3 ;shift bit to be set to the least significant bit

    set 0,(hl) ;set that bit
    pop de ;recall d register again

    rrc (hl) ;CB0E
    dec d ;15   ;rotate in other direction to undo previous shifts
    jr nz,$-3

    pop bc ; recall values of b and c
;__________End pixel-on(b,c)_______________

    ld a,b
    cp 3Eh  ;if x!=94 then continue inner loop else continue outer loop.
    jp nz,inner

    ld a,c
    cp 5Eh  ;if y!=62 then continue outer loop else quit
    jp nz,outer

    ret

Last edited on 16 Nov 2013 19:11 by Jannes Braet Show more

Re: need some help with this program

Xeda Elnara 16 Nov 2013 18:58

Here are the issues I noted:
*Issues:
using rl d instead of rr d, you are rotating the remainder bits in reverse order
Using ld d,93h \ ld e,40h instead of ld de,9340h
Stopping at 3Eh and 5Eh, respectively.

If I had to guess, I would say you have a column that isn't set being the 8th column of pixels? Try using 5Fh :)

Also, too view the graph screen, use a bcall(_GrBufCpy) in your loop, but remember that it destroys registers. You are also using a really roundabout method for plotting pixels. Here is my rendition:

    ld hl,9340h
    ld bc,4080h    ;b=64, number of rows c=80h, pixel mask
OuterLoop:
    push bc
    ld b,12
InnerLoop:
    ld a,(hl)    ;get the byte in the graph buffer
    or c        ;bit-wise OR 'A' with 'C', essentially setting one bit
    ld (hl),a    ;store the new value back to the graph buffer
    push bc        ;push bc onto the stack
    push hl        ;push hl onto the stack
    bcall(_GrBufCpy)
    pop hl        ;pop last value from the stack to HL
    pop bc        ;pop last value from the stack to BC
    rrc c        ;rotate c. if the c flag is set, C has been rotated back to 80h, so we need to increment HL
    jr nc,InnerLoop
;No we increment HL, decrement B (12 bytes to a row)
    inc hl
    djnz InnerLoop
    pop bc
    djnz OuterLoop
    ret

It will be pretty slow, taking about 3 seconds to fill each line. if you would like, I can provide some much faster code, too.

EDIT: The bcall(_GrBufCpy) (I believe that is its name) is EF6A48

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Last edited on 16 Nov 2013 18:58 by Xeda Elnara Show more

Re: need some help with this program

Xeda Elnara 16 Nov 2013 19:33

Also, if you are using WabbitEmu, you can click on the calculator screen and drag and it takes a screenshot. Alternatively, you can use backspace to record a .gif.

Also, here is the faster code I was referring to:

    bcall(_GrBufCpy)
    di
    ld hl,9340h
    ld a,80h
    out (16),a
    ld c,a
    ld de,12
    in a,(16) \ rlca \ jr c,$-3    ;wait for the LCD to be ready
    ld a,20h
col:
    out (16),a
    inc a
    cp 2Ch
    push af
    ld b,40h
row:
    in a,(16) \ rlca \ jr c,$-3
    ld a,(hl)
    or c
    ld (hl),a
    add hl,de
    out (17),a
    djnz row
    dec h
    dec h
    dec h
    rrc c
    jr nc,row-2
    inc l
    in a,(16) \ rlca \ jr c,$-3
    pop af
    jp nz,col
    ret

It theoretically displays every pixel, but it still happens way to quickly to see. To make it possible to see, I included about 22.75 million wasted clock cycles here:

    bcall(_GrBufCpy)
    di
    ld hl,9340h
    ld a,80h
    out (16),a
    ld c,a
    ld de,12
    in a,(16) \ rlca \ jr c,$-3    ;wait for the LCD to be ready
    ld a,20h
col:
    out (16),a
    inc a
    cp 2Ch
    push af
    ld b,40h
row:
    push bc
    ld b,128
    nop \ nop \ nop \ nop
    djnz $-4
    pop bc
    ld a,(hl)
    or c
    ld (hl),a
    add hl,de
    out (17),a
    djnz row
    dec h
    dec h
    dec h
    rrc c
    jr nc,row-2
    inc l
    in a,(16) \ rlca \ jr c,$-3
    pop af
    jp nz,col
    ret

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0

Re: need some help with this program

Jannes Braet 16 Nov 2013 19:52

Very clever solution once again. You are really good at this :)

And I just implemented some kind of algorithm which I found on some website so that's why it is not really good. But although I am quite sure it is rl and not rr.
If the carry bit is set three times then the value would become 00000111 with and rl which is what I want. since there are only 8 bits.

And in your faster code could you comment out a few more things?
And what does di do? EDIT: I found this but I didn't understand it:
Resets both interrupt flip-flops, thus prenting maskable interrupts from triggering.

And I can't rememeber what out (16),a
and in a,(16) did so could you explain please?

Last edited on 16 Nov 2013 20:06 by Jannes Braet Show more

Re: need some help with this program

Xeda Elnara 16 Nov 2013 20:14

out (16),a and in a,(16) write and read tot he LCD Instruction port (port 17 is the LCD data port).

As to the question of rotating the bits, while yes, you do want the lower 3 bits to contain the value, you are rotating them out of order. For example, if B=3, and D=0, then srl b / rl d 3 times would make B=0, D=6, or if B=1, D would end up being 4. What I would do is something more like the following:

ld a,b \ and %00000111 \ ld d,a
srl b \ srl b \ srl b

Check out the pixel plotting routine on this page.

'di' stands for 'Disable Interrupts.' The OS interrupt is what controls things such as processing the keyboard or running the run indicator, blinking the cursor, et cetera, and it runs in the back ground, so to speak. Since it messes with the LCD and the code I was using works directly with the LCD (instead of with the bcall), I just disabled them.

---

Z80 Assembly>English>TI-BASIC>Python>French>C>0